'==========================================================================
'
' VBScript Source File -- Created with SAPIEN Technologies PrimalScript 2009
'
'
'==========================================================================

Function RegExMatch(strString,strPattern)
    Dim RegEx
    RegExMatch=False
    
    Set RegEx = New RegExp				
    RegEx.IgnoreCase = True				
    RegEx.Global=True                   
    RegEx.Pattern=strPattern
    
    If RegEx.Test(strString) Then RegExMatch=True

End Function 

Function GetMatch(strString,strPattern)
    Dim RegEx,arrMatches
    Set RegEx = New RegExp				
    RegEx.IgnoreCase = True				
    RegEx.Global=True                   
    RegEx.Pattern=strPattern
    Set colMatches=RegEx.Execute(strString)
    Set GetMatch=colMatches
End Function

'simple matching
strString="SAPIEN Technologies"
strPattern="\w+"
If RegExMatch(strString,strPattern) Then
    Set matches=GetMatch(strString,strPattern)
    WScript.Echo "Found " & matches.count & " matches"
    For Each match In matches
        WScript.Echo match.value
    Next
End If


'Validation
strString="123.45.67.89"
strPattern="^\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}$"

If RegExMatch(strString,strPattern) Then 
    WScript.Echo strString & " looks like a valid IP address."
Else
    WScript.Echo strString & " does NOT look like a valid IP address."
End If

'Matching
strString="2009-04-14 15:00:53 172.16.10.1 PROPFIND /admin$. - 80 - 172.16.10.102 Microsoft-WebDAV-MiniRedir/6.0.6001 403 2 0"
strPattern="\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}"

If RegExMatch(strString,strPattern) Then
    Set matches=GetMatch(strString,strPattern)
    For Each match In matches
     'ignore the web server IP
     If match.value <> "172.16.10.1" then
        WScript.Echo match.value
     End If
    Next
End If